www/flake.nix

# This Source Code Form is subject to the terms of the Mozilla Public
# License, v. 2.0. If a copy of the MPL was not distributed with this
# file, You can obtain one at https://mozilla.org/MPL/2.0/.
# SPDX-License-Identifier: MPL-2.0
{
  inputs = {
    devshell = {
      url = "github:numtide/devshell";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.systems.follows = "systems";
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs.systems.follows = "systems";
    };
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    systems.url = "github:nix-systems/default";
    zerm = {
      url = "github:ejmg/zerm";
      flake = false;
    };
  };
  outputs = {
    devshell,
    flake-utils,
    nixpkgs,
    zerm,
    ...
  }: (flake-utils.lib.eachDefaultSystem (system: let
    pkgs = import nixpkgs {
      inherit system;
      overlays = [devshell.overlays.default];
    };
    pkg = pkgs.stdenv.mkDerivation {
      pname = "averywinters.org";
      version = "1.0.0";
      src = ./.;
      nativeBuildInputs = [pkgs.zola];
      configurePhase = ''
        mkdir -p themes
        ln -snf "${zerm}" "themes/zerm"
      '';
      buildPhase = "zola build";
      installPhase = "cp -r public $out";
    };
  in {
    formatter = pkgs.alejandra;
    devShells.default = let
      commands = [
        {package = pkgs.zola;}
      ];
      startupScript = ''
        mkdir -p themes
        ln -snf "${zerm}" "themes/zerm"
      '';
    in
      pkgs.devshell.mkShell {
        inherit commands;
        devshell.startup.themes.text = startupScript;
      };
    packages.default = pkg;
    overlays.default = final: prev: {
      www = pkg;
    };
  }));
}